Chapter 15

RESUMES

A clean, well-prepared resume may not always guarantee that you'll land your next job, but it sure can help. Some people write just one resume and send copies to all prospective employers; others tailor each resume to the particular job they are applying for. Either way, you will find WordPerfect macros a welcome addition to your job hunting tool box.

A resume macro not only helps you assemble your resume in one of several accepted formats, but it allows you to easily update or change it as need arises. Too, you may be in the business of preparing resumes for others. If so, a resume macro will save you valuable time and effort.

There are several common formats of resumes. This chapter details the design and use of macros for the two most popular types:

You will also learn how to enter boilerplate text into the resume while the macro is executing.

 

BUILDING SKILL-FORMAT RESUMES

The skill-format resume emphasizes achievement in past jobs or in school. It is most often used by job candidates with specific qualifications that are suited for the desired position. The format makes it easy for employers to see a broad overview of what you believe your major skills are. The format can also be used to camouflage periods of unemployment or jobs you've had that didn't promote your career plans. Good personnel directors know all the ins and outs of skill-format (also called functional or achievement) resumes, so it's best not to try to bury your past too much.

The disadvantage of the skill-format resume is that it is often hard to prepare because it requires strict observation of style. The following macro allows you to build a skill-format resume merely by "filling in the blanks." What you enter into these blanks makes all the difference in the world, so take your time to consider your skills, digest them into actual achievements and accomplishments you have made, then start the macro.

The skill-format resume macro uses a simple template document named RESUME.TMP. The template includes your name, address, and telephone number centered at the top of the page. These formatting codes were used with the prototype resume macro:

Add two or three blank lines below your name and address.


RESUME1.WPM (provided on the Applications Disk)

1.  {ON CANCEL}{GO}cancel~~
    {Retrieve}resume.tmp{Enter}
    {Home}{Home}{Down}

2.  {Bold}JOB OBJECTIVE{Bold}{Enter}
    {Indent}
    {STATUS PROMPT}Enter job objective; press Exit when done~
    {CALL}xit~
3.  {Bold}SUMMARY{Bold}{Enter}
    {Indent}
    {STATUS PROMPT}Enter skills summary; Exit when done~
    {CALL}xit~
4.  {Bold}PROFESSIONAL SKILLS{Bold}{Enter}
    {Indent}
    {STATUS PROMPT}Enter professional skills; Exit when done~
    {CALL}xit~
5.  {Bold}WORK EXPERIENCE{Bold}{Enter}
    {Indent}
    {STATUS PROMPT}Enter work experience; Exit when done~
    {CALL}xit~
6.  {Bold}EDUCATION{Bold}{Enter}
    {Indent}
    {STATUS PROMPT}Enter education; Exit when done~
    {CALL}xit~
7.  {Bold}PROFESSIONAL MEMBERSHIPS{Bold}{Enter}
    {Indent}
    {STATUS PROMPT}Enter professional memberships; Exit when done~
    {CALL}xit~
8.  {Bold}PERSONAL DATA{Bold}{Enter}
    {Indent}
    {STATUS PROMPT}Enter personal data; Exit when done~
    {CALL}xit~
    {GO}cancel~
9.  {LABEL}xit~
    {ASSIGN}key~~
    {LABEL}loop~
    {LOOK}key~
    {IF}"{VARIABLE}key~"="{Exit}"~
        {Enter}{Enter}
        {RETURN}
    {ELSE}
        {VARIABLE}key~
        {IF}"{VARIABLE}key~"="{Enter}"~
            {Enter}{Indent}
            {GO}loop~
        {ELSE}
            {GO}loop~
	{END IF}
    {END IF}
10. {LABEL}cancel~
    {STATUS PROMPT}~
    {QUIT}

Note that the macro does not pass the actual keystrokes of the Exit or [Enter] keys to the resume, but are trapped in the macro subroutine. The subroutine acts to temporarily redefine the Exit and [Enter] keys and produce the effects described. The macro automatically double spaces between categories and indents at every line.

If you don't want the paragraphs indented, use the macro that follows instead. It is nearly identical to RESUME1.WPM except for the following:


RESUME2.WPM (provided on the Applications Disk)

{ON CANCEL}{GO}cancel~~
{Retrieve}resume.tmp{Enter}
{Home}{Home}{Down}

{Bold}JOB OBJECTIVE{Bold}{Enter}
{STATUS PROMPT}Enter job objective; Exit when done~
{CALL}xit~

{Bold}SUMMARY{Bold}{Enter}
{STATUS PROMPT}Enter skills summary; Exit when done~ {CALL}xit~

{Bold}PROFESSIONAL SKILLS{Bold}{Enter}
{STATUS PROMPT}Enter professional skills; Exit when done~
{CALL}xit~

{Bold}WORK EXPERIENCE{Bold}{Enter}
{STATUS PROMPT}Enter work experience; Exit when done~
{CALL}xit~

{Bold}EDUCATION{Bold}{Enter}
{STATUS PROMPT}Enter education; Exit when done~
{CALL}xit~

{Bold}PROFESSIONAL MEMBERSHIPS{Bold}{Enter}
{STATUS PROMPT}Enter professional memberships; Exit when done~
{CALL}xit~

{Bold}PERSONAL DATA{Bold}{Enter}
{STATUS PROMPT}Enter personal data; Exit when done~
{CALL}xit~
{STATUS PROMPT}~
{GO}finish~

{LABEL}xit~
  --{Indent} {ASSIGN}key~~
{LABEL}loop~
{LOOK}key~
{IF}"{VARIABLE}key~"="{Exit}"~
{Enter}{Enter}
{RETURN}
{ELSE}
{IF}"{VARIABLE}key~"="{Enter}"~
{Enter}{Enter}
  --{Indent}
{GO}loop~
{ELSE}
{VARIABLE}key~
{GO}loop~
{END IF}{END IF}

{LABEL}finish~
{CHAR}key~{^\}Spell check resume ({^]}Y{^\}es/{^]}N{^\}o)?  
{^]}Y{^\}{Left}~
{CASE}{VARIABLE}key~~
{Enter}~spell~
Y~spell~    y~spell~
N~cancel~   n~cancel~
~
{GO}finish~
 {LABEL}spell~
{Home}{Home}{Up}
{Spell}3
{QUIT}

{LABEL}cancel~
{STATUS PROMPT}~
{QUIT}

Note the "finish" routine that asks if you want to spell check the document. The routine uses a {CASE} structure that tests for the [Enter] key, as well as upper- and loser-case Y and N. The [Enter] key does the same thing as the Y and y keys, so you can just press [Enter] at the prompt.

 

BUILDING CHRONOLOGICAL-FORMAT RESUMES

A chronological-format resume lists your educational or employment history, typically starting with the most recent school or job first, then working back a reasonable period of time (the distance you go back in time depends on your background and the nature of the position you are applying for).

The chronological format is the most widely used and therefore the most familiar resume format to employers. The format is reasonably easy to prepare because you are simply retelling your personal history. The format is ideally suited if you have stayed in one career for most of your professional life, or have an outstanding track record with a small handful of previous employers. Its disadvantages are that it is difficult for you to highlight specific jobs and achievements and makes interruptions in your educational or vocational record very obvious.

The macro for building the chronological-format resume is a composite between RESUME1.WPM and RESUME2.WPM, above, but the biggest difference is that the categories and prompts have been changed.


RESUME3.WPM (provided on the Applications Disk)

{ON CANCEL}{GO}cancel~~
{Retrieve}resume.tmp{Enter}
{Home}{Home}{Down}

{Bold}PROFESSIONAL EDUCATION{Bold}{Enter}{Enter}
{Indent}
{STATUS PROMPT}Enter professional education; Exit when done.~
{CALL}xit~

{Bold}UNDERGRADUATE EDUCATION{Bold}{Enter}{Enter}
{Indent} {STATUS PROMPT}Enter undergraduate education; Exit when
done.~
{CALL}xit~

{Bold}EMPLOYMENT{Bold}{Enter}{Enter}
{Indent}
{STATUS PROMPT}Enter employment history; Exit when done.~
{CALL}xit~

{Bold}REFERENCES{Bold}{Enter}{Enter}
{Indent}
{STATUS PROMPT}Enter references; press Exit when done.~
{CALL}xit~
{GO}finish~

{LABEL}xit~
{ASSIGN}key~~
{LABEL}loop~
{LOOK}key~
{IF}"{VARIABLE}key~"="{Exit}"~
{Enter}{Enter}
{RETURN}
{ELSE}
{IF}"{VARIABLE}key~"="{Enter}"~
{Enter}{Indent}
{GO}loop~
{ELSE} {VARIABLE}key~
{GO}loop~
{END IF}{END IF}

{LABEL}finish~
{CHAR}key~{^\}Spell check document ({^]}Y{^\}es/{^]}N{^\}o)?  
{^]}Y{^\}{Left}~
{CASE}{VARIABLE}key~~
{Enter}~    spell~
Y~spell~    y~spell~
N~cancel~   n~cancel~
~
{GO}finish~

{LABEL}spell~
{Home}{Home}{Up}
{Spell}3
{QUIT}

{LABEL}cancel~
{STATUS PROMPT}~
{QUIT}

The organization of the prompts assume you want to emphasize your education over employment. If your job history is your strong suit, put it first.

Since most people prefer to write "References available upon request" under the REFERENCES heading, you may want to automatically enter the text with the macro. Change that step so that always prints out:

REFERENCES
References available upon request. 


Remove the prompt so the macro no longer stops at the REFERENCES heading.

 

COMPLETE ENTRY RESUMES

The three resume macros presented so far in this chapter have used the same RESUME.TMP template document. This document includes your name, address, and telephone number, as well as codes for formatting the document. The macro that appears below does everything including setting the formats and asking for a name, address, and telephone, number. The macro uses the chronological-format resume style described for the RESUME3.WPM macro. You can easily modify it so that it produces resumes using other formats.

RESUME4.WPM (provided on the Applications Disk)

1.  {ON CANCEL}{GO}cancel~~
    {DISPLAY OFF}
    {Format}LWY{Enter}
    PNP2{Enter}
    UPY{Enter}{Exit}
    {DISPLAY ON}
2.  {Bold}{Center}
    {PROMPT}Enter name~
    {PAUSE KEY}{Enter}~{Enter}
    {Center}
    {PROMPT}Enter street~
    {PAUSE KEY}{Enter}~{Enter}
    {Center}
    {PROMPT}Enter city, state, and ZIP.~
    {PAUSE KEY}{Enter}~{Enter}
    {Bold}{Center}
    {PROMPT}Enter telephone number~
    {PAUSE KEY}{Enter}~{Enter}
    {Enter}{Enter}
3.  {Bold}PROFESSIONAL EDUCATION{Bold}{Enter}{Enter}
    {Indent}
    {STATUS PROMPT}Enter professional education; Exit when done.~
    {CALL}xit~
4.  {Bold}UNDERGRADUATE EDUCATION{Bold}{Enter}{Enter}
    {Indent} 
    {STATUS PROMPT}Enter undergraduate education; Exit when done.~
    {CALL}xit~
5.  {Bold}EMPLOYMENT{Bold}{Enter}{Enter}
    {Indent}
    {STATUS PROMPT}Enter employment history; Exit when done.~
    {CALL}xit~
6.  {Bold}REFERENCES{Bold}{Enter}{Enter}
    {Indent}
    {STATUS PROMPT}Enter references; Exit when done.~
    {CALL}xit~
    {STATUS PROMPT}~
    {GO}finish~
7.  {LABEL}xit~
    {ASSIGN}key~~
    {LABEL}loop~
    {LOOK}key~
    {IF}"{VARIABLE}key~"="{Exit}"~
        {Enter}{Enter}
        {RETURN}
    {ELSE}
        {IF}"{VARIABLE}key~"="{Enter}"~
            {Enter}{Indent}
            {GO}loop~
    {ELSE}
            {VARIABLE}key~
            {GO}loop~ 
        {END IF}
    {END IF}
8.  {LABEL}finish~
    {CHAR}key~{^\}Spell check document ({^]}Y{^\}es/{^]}N{^\}o)?  
    {^]}Y{^\}{Left}~
    {CASE}{VARIABLE}key~~
      {Enter}~spell~
      Y~spell~    y~spell~
      N~cancel~   n~cancel~
      ~{GO}finish~
9.  {LABEL}spell~
    {Home}{Home}{Up}
    {Spell}3
    {QUIT}
10. {LABEL}cancel~
    {STATUS PROMPT}~
    {DISPLAY OFF}
    {DISPLAY ON}
    {QUIT}

 

ENTERING BOILERPLATE TEXT WHILE BUILDING A RESUME

If you are plan on sending custom-made resumes to various employers, you'll find it easier if you store common resume entries as text-only macros (macros that contain only text and no formatting codes). For example, your text-only macros might have one or two variations of your job objective, skills summary, or work experience. Or you might keep your educational background, which stays the same for most resumes, in a text-only macro for easy recall. You may store the text as [Alt]-letter key macros or named macros.

To use the system of resume macros, start the main macro (RESUME1.WPM through RESUME4.WPM), then instead of typing text directly from the keyboard, invoke one of the macros. If you're creating a lot of versions of your resume for employers, you may want to use one of the menu systems outlined in Chapter 5. That way, you can pick the macros to use from an on-screen list. Each segment of the resume calls up a different menu.

---

 Top Contents

WordPerfect 5.1 Macros and Templates
Electronic Edition
Copyright 1990, 1997, Gordon McComb.  All Rights Reserved.
First published by Bantam Electronic Publishing, 1990.
http://www.gmccomb.com/