Chapter 11

LAW PRACTICE

Among the popular word processors for the IBM PC and compatibles, WordPerfect is the program of choice for lawyers and others in the legal trade. WordPerfect offers numerous feature that are well adapted for use in law practice, including table of authorities, line numbering, and automatic paragraph numbering (these features are useful to other users, as well, but they are particularly handy for the lawyer).

Of course, macros and merges can be effectively used to simplify common legal document tasks, such as writing contracts, filling out deposition notices, and completing forms necessary for service of process in federal cases. This chapter details several such macros.

The author wishes to thank Edward Still, lawyer and fellow macro enthusiast, for allowing him to use his DEPONOT.WPM, FEDSERV.WPM, and GENDER.WPM macros for this chapter.

 

DEPOSITION NOTICE

The macro/merge system that follows allows you to quickly and easily prepare deposition notices, in accordance to standard legal practice in your area (you may have to edit the sample deposition form as required). Obviously, you'll need to also change those parts of the merge file and macro that refer to the attorneys in your office, the judicial districts in your state, and the names of each clerk.

The deposition notice system is composed of two major elements: a macro and a merge. The primary merge document, named DEPONOT.MRG, executes the two macros -- named AGAIN.WPM AND DEPONOT.WPM.

When the merge is first run, it cleans out the variables used to contain the deposition information. The DEPONOT.WPM macro then prompts you for the values to assign to the variables. The merge is used to film in the deposition form, using the variables you assigned earlier. Finally, the AGAIN.WPM macro asks if you want to merge again; if you do, it loops back to the top of the document, just below the commands that clean out the variables. Thus, in the second loop, the variables can be used again just by pressing the [Enter] key.

Note: Before starting DEPONOT.WPM, you should prepare two documents: a case caption for the beginning of the deposition notice, and the attorney signature block. You can name these files as desired. You are prompted for the name and path (if any) for these files when you run DEPONOT.WPM.


DEPONOT.WPM (provided on the Applications Disk)

1.  {TEXT}newcaption~{Del to EOP}

    Type the full path name for the  
    CASE CAPTION then hit <enter>{Enter} 
    example:  \wp\smith\cap{Enter} {^]}Present value: {VARIABLE}caption~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newcaption~"=""~ 
    {ELSE} 
         {ASSIGN}caption~{VARIABLE}newcaption~~ 
    {END IF} 

2.  {TEXT}newourclient~{Del to EOP}

    Type "plaintiff(s)/ defendant(s)" for OUR CLIENT,   
    then <enter>{Enter} 
    {^]}Present value: {VARIABLE}ourclient~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newourclient~"=""~ 
    {ELSE} 
       {ASSIGN}ourclient~{VARIABLE}newourclient~~ 
    {END IF} 

3.  {TEXT}newdeponent~{Del to EOP}

    Type in DEPONENT AND ADDRESS,     then hit <enter>{Enter} 
    {^]}Present value: {VARIABLE}deponent~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newdeponent~"=""~ 
    {ELSE} 
       {ASSIGN}deponent~{VARIABLE}newdeponent~~ 
    {END IF}  
4.  {TEXT}newlocation~{Del to EOP}

    Type in LOCATION of deposition,  
    then hit <enter>{Enter} 
    {^]}Present value: {VARIABLE}location~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newlocation~"=""~ 
    {ELSE} 
       {ASSIGN}location~{VARIABLE}newlocation~~ 
    {END IF} 

5.  {TEXT}newhour~{Del to EOP}

    Type in HOUR, then hit <enter>{Enter} 
    {^]}Present value: {VARIABLE}hour~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newlocation~"=""~ 
    {ELSE} 
       {ASSIGN}hour~{VARIABLE}newhour~~ 
    {END IF} 

6.  {TEXT}newday~{Del to EOP}

    Type in DAY, then hit <enter>{Enter} 
    {^]}Present value: {VARIABLE}day~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newday~"=""~ 
    {ELSE}
        {ASSIGN}day~{VARIABLE}newday~~ 
    {END IF}

7.  {TEXT}newmonth~{Del to EOP}

    Type in MONTH, then hit <enter>{Enter} 
    {^]}Present value: {VARIABLE}month~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newmonth~"=""~ 
    {ELSE} 
       {ASSIGN}month~{VARIABLE}newmonth~~ 
    {END IF} 

8.  {TEXT}newyear~{Del to EOP}

    Type in YEAR, then hit <enter>{Enter} 
    {^]}Present value: {VARIABLE}year~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newyear~"=""~ 
    {ELSE} 
       {ASSIGN}year~{VARIABLE}newyear~~ 
    {END IF} 

9.  {TEXT}newlist~{Del to EOP}

    Type in LIST OF DOCUMENTS needed from  
    deponent, then hit <enter>{Enter} 
    {^]}Present value: {VARIABLE}list~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~      
{IF}"{VARIABLE}newlist~"=""~ 
    {ELSE} 
       {ASSIGN}list~{VARIABLE}newlist~~ 
    {END IF} 

10. {CHAR}newcorporation~{Del to EOP}

    Is the deponent a CORPORATION? Y/N{Enter} 
    {^]}Present value: {VARIABLE}corporation~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newcorporation~"=""~ 
    {ELSE} 
       {ASSIGN}corporation~{VARIABLE}newcorporation~~ 
    {END IF} 

11. {GO}corp_{VARIABLE}corporation~~ 

    {LABEL}corp_y~ 
    {TEXT}newquestions~{Del to EOP}

    Type in QUESTIONS FOR DEPONENT,  
    then hit <enter>{Enter} 
    {^]}Present value: {VARIABLE}questions~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newquestions~"=""~ 
    {ELSE} 
       {ASSIGN}questions~{VARIABLE}newquestions~~ 
    {END IF}  

    {LABEL}corp_n~ 
    {CHAR}newsubpoena~{Del to EOP}

    Do you need a SUBPOENA?  Y/N{Enter} 
    {^]}Present value: {VARIABLE}subpoena~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newsubpoena~"=""~ 
    {ELSE} 
       {ASSIGN}subpoena~{VARIABLE}newsubpoena~~ 
    {END IF} 

12. {GO}subpoena_{VARIABLE}subpoena~~ 

    {LABEL}subpoena_y~ 
    {CHAR}newdistrict~{Del to EOP}

    Type in N, M, or S for the FEDERAL DISTRICT,     
    then hit <enter>{Enter} 
    {^]}Present value: {VARIABLE}district~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newdistrict~"=""~ 
    {ELSE} 
       {ASSIGN}district~{VARIABLE}newdistrict~~ 
    {END IF} 

13. {TEXT}newattorney~{Del to EOP}

    Type in last name of ATTORNEY, then hit <enter>{Enter}      
{^]}Present value: {VARIABLE}attorney~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newattorney~"=""~ 
    {ELSE} 
       {ASSIGN}attorney~{VARIABLE}newattorney~~ 
    {END IF} 

14. {LABEL}subpoena_n~ 
    {TEXT}newsig~{Del to EOP}

    Type full path of SIG for the case{Enter} 
    example:  \wp\smith\sig{Enter} 
    {^]}Present value: {VARIABLE}sig~{^\}{Enter} 
    (hit <enter> to accept this or enter new value){Enter}~ 
    {IF}"{VARIABLE}newsig~"=""~ 
    {ELSE} 
       {ASSIGN}sig~{VARIABLE}newsig~~ 
    {END IF} 

15. {Screen}{Screen} 
    {QUIT}

AGAIN.WPM (provided on the Applications Disk)

{DISPLAY OFF} 
{CHAR}again~ 
{Del to EOP}{^P} 
Do you want to run the merge again? Y/N  ~

DEPONOT.MRG (provided on the Applications Disk)

{COMMENT}
NAME: DEPONOT.MRG

PURPOSE: fill in notice of deposition and subpoena; loop to repeat

SECONDARY FILE: none

MACROS: DEPONOT.WPM, AGAIN.WPM

~{ASSIGN}caption~~{ASSIGN}ourclient~~{ASSIGN}deponent~~{COMMENT}
~{ASSIGN}location~~{ASSIGN}hour~~{ASSIGN}day~~{COMMENT}
~{ASSIGN}month~~{ASSIGN}year~~{ASSIGN}corporation~~{COMMENT}
~{ASSIGN}questions~~{ASSIGN}list~~{ASSIGN}sig~~{COMMENT}
~{ASSIGN}district~~{ASSIGN}attorney~~{ASSIGN}subpoena~~{COMMENT}
~{ASSIGN}again~~{COMMENT}

~{LABEL}again_y~{NEST MACRO}deponot~
{DOCUMENT}{VARIABLE}caption~~

  Notice of Deposition 
 
Please take notice that the {VARIABLE}ourclient~ will take the
deposition of {VARIABLE}deponent~ upon oral examination before a
notary public or some other officer authorized by law to administer
oaths at {VARIABLE}location~ at {COMMENT}
~{VARIABLE}hour~ on {VARIABLE}day~ {VARIABLE}month~ {COMMENT}
~{VARIABLE}year~ {COMMENT}
~and continuing from day to day until completed. 
{GO}corp_{VARIABLE}corporation~~{COMMENT}
~{LABEL}corp_y~{COMMENT}
~    The named organization should appoint one or more persons
knowledgeable regarding the following:  {VARIABLE}questions~. 
The deponent is requested to bring to the deposition the following
documents:  all documents which the deponent has reviewed or may need
to review to refresh his recollection concerning the subject matter of
this action and the matters listed above; {VARIABLE}list~. The
deponent will be asked to testify on the subject matter and
authenticity of the documents listed above. 
{GO}signature~{COMMENT}
~{LABEL}corp_n~{COMMENT}
~    The deponent is requested to bring to the deposition the
following documents:  all documents which the deponent has reviewed or
may need to review to refresh his recollection concerning the subject
matter of this action; {VARIABLE}list~.
{LABEL}signature~{DOCUMENT}{VARIABLE}sig~~
cc: 

{GO}subpoena_{VARIABLE}subpoena~~{COMMENT}
~{LABEL}subpoena_y~
{VARIABLE}caption~~
  Deposition Subpoena 
 
TO:  {VARIABLE}deponent~
YOU ARE COMMANDED to appear at {VARIABLE}location~ at {COMMENT}
~{VARIABLE}hour~ on {VARIABLE}day~ {VARIABLE}month~ {COMMENT}
~{VARIABLE}year~ {COMMENT}
~to testify on behalf of {VARIABLE}ourclient~ {COMMENT}
~at the taking of a deposition in the above entitled action and bring
with you the following documents:  all documents which you have
reviewed or may need to review for refreshing your recollection
concerning the subject matter of this action;
{COMMENT}~{VARIABLE}list~.
Any subpoenaed organization not a party to this suit is hereby
admonished pursuant to Rule 30(b)(6), Federal Rules of Civil
Procedure, to file a designation with the Court specifying one or more
officers, directors, managing agents, or other persons who consent to
testify on its behalf, and shall set forth, for each person
designated, the matters on which he will testify or produce documents
or things.  The person(s) so designated shall testify as to matters
known or reasonably available to the organization.  The designated
deponent(s) should be knowledgeable regarding the following: 
{VARIABLE}questions~.

{GO}dist_{VARIABLE}district~~{COMMENT}
~{LABEL}dist_m~{COMMENT}
~    ______________
date Hon. xxxxxxxxxxxxxxxx, Clerk
{GO}after_clerk~{LABEL}dist_n~{COMMENT}
~    ______________ 
date Hon. xxxxxxxxxxxxxxxx, Clerk
{GO}after_clerk~{LABEL}dist_s~{COMMENT}
~    ______________ 
date Hon. xxxxxxxxxxxxxxxx, Clerk
{LABEL}after_clerk~
by:________________________
Deputy Clerk
(Seal of Court)

 
 
___________________________ 
REQUESTED BY: 
{GO}atty_{VARIABLE}attorney~~{COMMENT}
~{LABEL}atty_x~Attorney X 
{GO}after_atty~{LABEL}atty_y~Attorney Y 
{LABEL}after_atty~<<Address> 
<City, State, ZIP>
<Phone Number>

 
    RETURN OF SERVICE ON WRIT 
 
I hereby certify that on the ____ day of _________________, 19___, I
served the attached subpoena (and the fee for attendance) by personal
service on 
 
{VARIABLE}deponent~
 

Under penalty of perjury, I affirm that the foregoing statement is
true and correct.  
Executed this ___ day of ________, 19___. 
 
 
_______________________________ 
Process Server 
 
Costs of Personal Service: 
Fee for Personal Service:$  
 
Expenses: ___ miles @ 22 cents$________ 
 
TOTAL:    $ 
 
{LABEL}subpoena_n~
{NEST MACRO}again~{GO}again_{VARIABLE}again~~{COMMENT}
~{LABEL}again_n~{REWRITE}

In the REQUESTED BY: heading of the deposition notice, the merge
document provides two alternatives -- X and Y -- for the name of the
filing attorney.  Edit these attorney names with ones that are more
descriptive, such as "Mike" or "Silverstein."  You can include as many
names as there are attorneys in your office.  These are the names you
enter in Step 13 of the DEPONOT.WPM macro.


SERVICE OF PROCESS IN FEDERAL CASES

Macros and templates make short order of creating the documents necessary for service of process in federal cases. A macro, named FEDSERV.WPM, is used for filling in the blanks of the series of template documents.

The forms used with the FEDSERV.WPM are arranged for the federal courts for the state of Alabama; you'll have to modify the system for your own requirements. Because the forms are standard WordPerfect documents, you can readily edit them as needed. Note that the summons in Part3N is not the official Form 1 but a modification ordered by the US District Court for the Northern District of Alabama.

The FEDSERV.WPM macro assumes that the forms are located in the default document directory (either the current WordPerfect directory, or the directory you've assigned with the Location of Files option to hold your documents). If the forms are located someplace else -- on another disk or in another directory -- you should modify the FEDSERV.WPM macro and include the full disk and directory path.


FEDSERV.WPM (provided on the Applications Disk)

{TEXT}1~{BELL}{Del to EOP}  WARNING: the other document must be empty
for this {Enter} 
macro to work properly.  {Enter} 
If it is not clear, abort the macro by pressing <F1>. 
{Enter}{Enter}{Enter} 
Type the exact path and filename {Enter}of the  
caption of the case and press <enter>{Enter}>>>~ 
 
{Retrieve}{VAR 1}{Enter} 
 
{CHAR}6~{^P}{^A}{^D}{Left}{Del to EOL} 
In what district is this case to be filed?{Enter}
{Del to EOL} 
Northern   Type N {Enter}{Del to EOL} 
Middle     Type M {Enter}{Del to EOL} 
Southern   Type S {Enter}{Del to EOL}>>>~ 
 
{DISPLAY OFF} 
{Home}{Home}{Up}{Block}{Home}{Home}{Down} 
{Delete}y 
{DISPLAY ON} 
 
{LABEL}defendant~ 
{TEXT}2~ 
{Del to EOP}Type the name of the defendant to be 
served{Enter} 
and press <enter>{Enter}>>>~   
{TEXT}3~ 
{Del to EOP}Type the 1st address line of the defendant 
and press <enter>{Enter}>>>~ 
 
{TEXT}4~ 
{Del to EOP}Type the 2nd address line of the defendant 
and press <enter>{Enter}>>>~ 
 
{TEXT}5~ 
{Del to EOP}Type the 3rd address line of the defendant 
and press <enter>{Enter}     (this must be the last 
line){Enter}>>>~ 
 
{CHAR}7~ 
{Del to EOP}CERTIFIED MAIL is used when the defendant 
is a governmental entity{Enter} 
(but not a governmental official).  Which method of 
service should {Enter} 
be used?{Enter}{Enter} 
CERTIFIED MAIL   Type C {Enter} 
REGULAR SERVICE  Type R {Enter}>>>~ 
 
{TEXT}8~ 
{Del to EOP}What DATE will the service be sent?{Enter}>>>~ 
  {Switch} 
{Retrieve}{VAR 1}{Enter} 
{Home}{Home}{Down}{End Field}{Enter} 
{VAR 2}{End Field}{Enter} 
{VAR 3}{End Field}{Enter} 
{VAR 4}{End Field}{Enter} 
{VAR 5}{End Field}{Enter} 
{VAR 6}{End Field}{Enter} 
{VAR 7}{End Field}{Enter} 
{VAR 8}{End Field}{Enter}{Merge Codes}E 
{Exit}y 
fedtemp.tpm{Enter}yn{Switch} 
 
{Merge/Sort}M 
part2.tmp{Enter} 
fedtemp.tpm{Enter} 
 
{CHAR}0~{Del to EOP}Is there another defendant to be 
served?{Enter}
Type  Y or N{Enter}>>>~ 
{CASE}{VAR 0}~
Y~defendant~   y~defendant~
N~end~    n~end~
~ 
{LABEL}end~ {Screen}{Screen} 

FEDSERV.WPM TEMPLATES (provided on the Applications Disk)

PART2.TMP

{FIELD}1~
To:  {FIELD}2~
{FIELD}3?~
{FIELD}4?~
{FIELD}5?~

    Summons

You are hereby summoned and required to serve upon plaintiff's
attorney,
<Name>
<Address>
<City, State, ZIP>

{NEST PRIMARY}part3{FIELD}6~.tmp~

PART3N.TMP

a response to the complaint which is herewith served upon you, within
20 days after service of this summons upon you, exclusive of the day
of service.  IF YOU FAIL TO DO SO, JUDGMENT BY DEFAULT MAY BE TAKEN
AGAINST YOU FOR THE RELIEF DEMANDED IN THE COMPLAINT.  A signed copy
of your response MUST also be filed with the court.

______________ 
date Hon. xxxxxxxxxxxxxxxx, Clerk

by:________________________
Deputy Clerk

    (Seal of Court)


(This summons is issued pursuant to Rule 4 of the Federal Rules of
Civil Procedure.)

============================================
{NEST PRIMARY}part4{FIELD}7~.tmp~

PART3M.TMP

an answer to the complaint which is herewith served upon you, within
20 days after service of this summons upon you, exclusive of the day
of service.  If you fail to do so, judgment by default will be taken
against you for the relief demanded in the complaint. 

______________ 
date Hon. xxxxxxxxxxxxxxxxxx, Clerk

by:________________________
Deputy Clerk

    (Seal of Court)


(This summons is issued pursuant to Rule 4 of the Federal Rules of
Civil Procedure.)

=================================
{NEST PRIMARY}part4{FIELD}7~.tmp~

PART3S.TMP

an answer to the complaint which is herewith served upon you, within
20 days after service of this summons upon you, exclusive of the day
of service.  If you fail to do so, judgment by default will be taken
against you for the relief demanded in the complaint.

______________ 
date Hon. xxxxxxxxxxxxxxxxx, Clerk

by:________________________
Deputy Clerk

    (Seal of Court)


(This summons is issued pursuant to Rule 4 of the Federal Rules of
Civil Procedure.)

=================================
{NEST PRIMARY}part4{FIELD}7~.tmp~

PART4C.TMP

{SUBST SECONDARY}fedtemp.tmp~{FIELD}1~
    REQUEST FOR SERVICE BY CERTIFIED MAIL

I request that the Clerk serve {FIELD}2~ by certified mail in
accordance with Federal Rule 4(d)(6) and Alabama Rule 4.1(c)(2).  I
have prepared the proper envelopes and postal forms and attached them
hereto.

___________________________ <Name>
<Address>
<City, State, ZIP>

encl:
envelope addressed to the defendant with correct postage
green return receipt card addressed to clerk
certified mail sticker

================================
{NEXT RECORD}

PART4R.TMP

{SUBST SECONDARY}fedtemp.tmp~{FIELD}1~
    NOTICE

To:  
{FIELD}2~
{FIELD}3?~
{FIELD}4?~
{FIELD}5?~


The enclosed summons and complaint are served pursuant to Rule 4 (c)
(2) (C) (ii) of the Federal Rules of Civil Procedure.

You must complete the acknowledgment part of this form and return one
copy of the completed form to the sender within 20 days.

You must sign and date the acknowledgment.  If you are served on
behalf of a corporation, unincorporated association (including a
partnership), or other entity, you must indicate under your signature
your relationship to that entity.  If you are served on behalf of
another person and you are authorized to receive process, you must
indicate under your signature your authority.

If you do not complete and return the form to the sender within 20
days, you (or the party on whose behalf you are being served) may be
required to pay any expenses incurred in serving a summons and
complaint in any other manner permitted by law.

If you do complete and return this form, you (or the party on whose
behalf you are being served) must answer the complaint within 20 days.

If you fail to do so, judgment by default will be taken against you
for the relief demanded in the complaint.

I declare, under penalty of perjury, that this Notice and
Acknowledgment of Receipt of Summons and Complaint was mailed on
{FIELD}8~. 
___________________________
<Address>
<City, State, ZIP>

    ACKNOWLEDGEMENT OF RECEIPT OF SUMMONS
 AND COMPAINT

I declare, under penalty of perjury, that I received a copy of the
summons and of the complaint in the above-captioned matter at (insert
address) ____________________________________________.

_____________________________
Signature


________________________________
Relationship to Entity/Authority to
Receive Service of Process

______________________________
Date of Receipt

encl:
prepaid return envelope
2 copies of this notice
summons
complaint

=======================================
{NEXT RECORD}


GENDER CHANGER

Increasingly, contracts and other legal documents are written gender specific, rather than using the "customary" he and his. The GENDER.WPM macro shown here lets you create universal documents, and alter the gender as needed. The macro is used with forms that have special markers in them in place of or as suffixes to nouns, pronouns, and verbs.

To use GENDER.WPM, first place markers in a primary merge form document. The form document is your contract, lien, escrow, or other legal document. Use the place marker %%1 for one party (usually the plaintiff); use %%2 for another; and so on. You can use any one digit or letter after "%%".

When you run the GENDER.WPM macro, it searches from the beginning of the document (including headers, footers, and footnotes) for the first occurrence of "%%." It then marks the word and ask you for the appropriate replacement. You must respond by choosing M, F, N, or P-- for male, female, neuter, plural. Next, the macro replaces the marked words with the proper pronoun, noun, or verb.

The macro will then loop back to the beginning of the document and search for the first occurrence of any other "%%" markers. The macro stops when all the markers have been changed. Or, you stop the macro at any point by pressing the Cancel key. It may be necessary to press it another time.

The GENDER.WPM macro comes encoded with the following phrases and gender substitutes.

marker    	male	female	neuter	plural
%%1each				each 
in place of the word each
		(because the macro does not backspace,
		please eliminate any space between the
		%%1each marker and the next word:
		EXAMPLE: %%1eachplaintiff)

%%1he in place of 
first person pronouns    
		he   	she  	it   	they

%%1his in place of the possessive 
pronouns 	his  	her  	its  	their

%%1him in place of the objective 
pronouns  	him  	her  	it   	them

 %%1noun at the end of any other noun that may 
change in number, example: 
owner%%1noun   	owner	owner	owner	owners

%%1verb at the end of any present tense verb, 
example: 
pay%%1verb	pays	pays	pays	pay

%%1be in place of the verb "to be"   
		is   	is   	is   	are

%%1do in place of the "to do"   
		does 	does 	does 	do

%%1have in place of the "to have" 
		has  	has  	has  	have

%%1poss at the end of any possessive noun 
that may change in number, example: 
owner%%1poss   	owner's	owner's	owner's	owners'

GENDER.WPM (provided on the Applications Disk)

{DISPLAY OFF} 
{LABEL}top~ 
{ON NOT FOUND}{GO}end~~ 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home} 
{Search}%%{Search} 
{Block}{Right}{Macro Commands}32 
{DISPLAY ON} 
{Word Left}{Block}{Word Right} 
 
{PROMPT}{^P}{^A}{^U}{Left}{Del to EOL} 
                              <a Peace B. Still macro> 
{^P}{^A}{^V}{Left}{Del to EOL}Enter sex and number for this marker as
follows:~ 
{CHAR}1~{^P}{^A}{Up}{Left}{Del to EOL}(M)ale   (F)emale   
(N)euter   (P)lural{Enter}~ 
 
{DISPLAY OFF}{Block}{;}turns off block~ 
{GO}{VAR 1}~ 
 
{LABEL}m~ 
{;}conversion for male~ 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}each
{Search}{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}he
{Search}he{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}his
{Search}his{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}him
{Search}him{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}noun
{Search}{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}verb
{Search}s{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}be
{Search}is{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}do
{Search}does{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}have
{Search}has{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}poss
{Search}'s{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up} 
{GO}top~ 
 
{LABEL}f~ 
{;}conversion for female~ 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}each
{Search}{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}he
{Search}she{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}his
{Search}her{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}him
{Search}her{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}noun
{Search}{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}verb
{Search}s{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}be
{Search}is{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}do
{Search}does{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}have
{Search}has{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}poss
{Search}'s{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up} 
{GO}top~ 
 
{LABEL}n~ 
{;}conversion for neuter~ 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}each
{Search}{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}he
{Search}it{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}his
{Search}its{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}him
{Search}it{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}noun
{Search}{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}verb
{Search}s{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}be
{Search}is{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}do
{Search}does{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}have
{Search}has{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}poss
{Search}'s{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up} 
{GO}top~ 
 
{LABEL}p~ 
{;}conversion for plural~ 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}each
{Search}each {Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}he
{Search}they{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}his
{Search}their{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}him
{Search}them{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}noun
{Search}s{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}verb
{Search}{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}be
{Search}are{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}do
{Search}do{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}have
{Search}have{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up}{Home}{Replace}n%%{VAR 2}poss
{Search}s'{Search} 
{IF}{STATE}&8~{Exit}{END IF} 
{Home}{Home}{Home}{Up} 
{GO}top~ 
 
{LABEL}end~ 
{IF}{STATE}&8~ 
{Exit} 
{END IF} 

You can add additional words and their gender variations to the GENDER.WPM macro. Included on the Applications Disk is GENDER.TST, which you can use to test the GENDER.WPM macro. For your reference, here is the text of the GENDER.TST file. You can also use it as a model for your own gender-changing document.


GENDER.TST (provided on the Applications Disk)

The donor%%1noun hereby give%%1verb %%1his entire library to the
charity%%2noun named below.  [You will notice that I have thrown a
monkey wrench into this immediately by using a word that does not
simply add "s" to make a plural.  You will find such words by running
the spelling checker immediately after this macro.]  The donor%%1noun
%%1have a simple desire; %%1he wish%%1verb %%1his books to be of some
service to the public at large.  Reposing full trust in the
director%%3noun of the charity%%2noun, the donor%%1noun appoint%%1verb
%%3him to make all decisions about the distribution of the
donor%%1poss books to the various libraries about the state.  The
donor%%1noun %%1be of sound mind, %%1have ample other resources, and
%%1do not wish to retain any interest in the books.

The document has a header and a footnote, both of which will be changed by the GENDER macro.

 

BOILERPLATE CONTRACTS

If you write more than a couple of contracts a month, you know how of much of a hassle the work can be. The legal ramifications of making a mistake require you to carefully prepare and produce each contract you write with WordPerfect. Using macros or merges can help ease the burden, but unless your contracts are very simple, or don't involve many variables, your chances of making errors and entering the wrong data is profoundly increased.

An on-screen menu system coupled with nested macros makes producing boilerplate contracts relatively painless -- and far more accurate. You can construct your contracts so that the standard boilerplate text is entered automatically, yet you are still given a chance to enter information that may change from contract to contract.

To explain how macros can be used to produce a contract, let's examine a typical author's agreement. Although it shows only the first page of an eight page contract, it offers a good example of the entire process. At the heart of the contract is the CONTRACT.WPM macro, which serves as a menu engine. The engine uses a separate menu list document, CONTRACT.TMP. The menu just about fills the screen with 22 items, although the system is designed so that you can have more items than will fit on one screen.

The unique aspect of the CONTRACT.WPM macro is that it highlights each menu item as you press the [Up] and [Down] cursor keys. After selecting a menu option, you simply press [Enter]and the corresponding boilerplate macro is activated. After the boilerplate macro is finished, you are returned to the list where you left off. When you are done, press [Ctrl]-[Enter], and the CONTRACT.WPM macro ends. The menu list is cleared, and you are presented with the completed contract.

The author's agreement, most contracts, uses numbered paragraphs as opposed to numbered lines. These paragraphs are labeled by name so that WordPerfect can automatically reference the paragraph numbers. For example, note the Paragraph reference in the fourth line from the end of "Publishing Rights." This reference ties the "rights" paragraph (in this case, Paragraph 6), that appears later in the contract.

The system of automatic referencing, which makes use of WordPerfect's feature of the same name, as well as the menu-driven engine of the macro, allows you to link the paragraphs of the contract in any order you wish. The paragraph numbers and auto-reference numbers are provided by WordPerfect, relieving you of keeping track of them yourself. This helps makes the system even more foolproof and easy to use.


The Contract Macro and List Menu

The CONTRACT.WPM macro engine is fairly straightforward. Its construction allows you to use it with any menu-based systems. Just change the name of the menu list file (CONTRACT.TMP in the example) as required. To work properly, your menu list file should be formatted the same as CONTRACT.TMP.

The menu list should contain no empty lines.


CONTRACT.WPM (provided on the Applications Disk)

1.  {ON ERROR}~ 
    {ON CANCEL}~ 
2.  {Switch} 
    {Retrieve}CONTRACT.TMP{Enter} 
    {DISPLAY ON} 
    {Home}{Home}{Up} 
3.  {ASSIGN}key~~ 
    {GO}highlight~ 
    {LABEL}loop~ 
    {ON CANCEL}{GO}cancel~~ 
    {LOOK}key~ 
4.  {IF}"{VARIABLE}key~"="{Down}"~ 
       {Block}{Home}{Left} 
       {Down} 
       {GO}highlight~ 
    {ELSE}
    {IF}"{VARIABLE}key~"="{Up}"~ 
       {Block}{Home}{Left} 
       {Up} 
       {GO}highlight~ 
    {ELSE} 
    {IF}"{VARIABLE}key~"="{Enter}"~ 
       {ON CANCEL}~ 
       {Block}{Word Left} 
       {Block}{Word Right} 
       {Macro Commands}Amacro{Enter} 
       {Switch} 
       {Home}{Home}{Down} 
       {NEST}{VARIABLE}macro~~{Enter} 
       {DISPLAY ON} 
       {Switch} 
       {Block} 
       {Home}{Left}{Up} 
       {GO}loop~ 
    {ELSE} 
    {IF}"{VARIABLE}key~"="{Hpg}"~ 
       {Block} 
       {Exit}nn 
       {Switch} 
       {DISPLAY OFF} 
       {Mark Text}GGy{Enter} 
       {DISPLAY ON}
       {QUIT} 
    {ELSE} 
    {END IF}{END IF}{END IF}{END IF} 
    {GO}loop~ 

5.  {LABEL}highlight~ 
    {Block} 
    {End} 
    {GO}loop~ 
  
6.  {LABEL}cancel~ 
    {Block} 
    {Exit}nn{Switch} 
    {QUIT}

Step 6 tells the macro to clear the CONTRACT.TMP screen and quit the macro. The macro selects or highlights, with the block function, each line in the menu list. Pressing the [Down] or [Up] keys moves the selection up or down. If you have more than about 24 items in the menu, the screen will scroll as you press the cursor keys. When you get to the line you want, pressing [Enter] reduces the block selection to the last column, which contains the actual name of the macro.


The Contract Sub-Macros

Each menu item refers to a separate macro. For example, the "Beginning of Contract" menu item calls up BEGIN.WPM. The design of the contract system allows you to use fairly descriptive names for each menu item yet still refer to each individual macro by its name of eight or less characters.

You are free to be as elaborate as you want in the construction of the sub-macros, but remember that they are themselves nested macros. Each nested macro can contain only one chained macro. The following macros show the first three sections of the author's agreement contract. Note that with the exception of the first section, the paragraph numbering and auto-referencing features are used to identify the paragraphs. The Date/Outline instruction in BEGIN.WPM formats the paragraph numbering using decimal numerals.

BEGIN.WPM (provided on the Applications Disk)

{DISPLAY OFF} 
{Date/Outline}DP{Enter}{Enter} 
{Enter} 
{Center}{Bold}AGREEMENT{Bold}{Enter}{Enter}{Enter} 
AGREEMENT made this {DISPLAY ON} 
{TEXT}key~Enter date  ~ 
{VARIABLE}key~, between  
{TEXT}key~Enter author name and address  ~ 
{VARIABLE}key~, hereinafter called Author, and MIRACLE BOOKS, INC.,
123 Main  Street, Los Angeles, CA  90023, hereinafter called
Publisher.{Enter} {Enter}  The parties hereto agree as
follows:{Enter}{Enter} 

The macro starts by turning the display off, setting the paragraph numbering definition to decimal (arabic) numerals, and printing AGREEMENT in bold letters at the top, center of the page. It then starts the agreement text, and stops for you to enter the date. Your entry is stored in variable key, then printed out when you press the [Enter] key. The process is repeated to allow you to enter the name and address of the author.

Note that while entering the name and address after the status line prompt, WordPerfect will reap the entry to the next line, but it make not break the line at a word. Though this looks awkward on the screen, the text will be formatted correctly in the document. Don't press the [Enter] key yourself to start a new line.

In addition, the screen will scroll up with each new line, and this could cause the text display to show duplicate lines. These lines are "ghosts" and will disappear when the screen is rewritten.


PUBRITE.WPM (provided on the Applications Disk)

{DISPLAY OFF} 
{Date/Outline}P{Enter} 
{Mark Text}RTpubrites{Enter} 
{Tab}PUBLISHING RIGHTS{Enter}{Enter}  Author hereby grants and assigns
exclusively to Publisher, during the  full term of copyright of the
work, the world publishing  English-language rights to publish and
sell a Work tentatively  called{Enter}{Enter}{DISPLAY ON} 
{TEXT}key~Enter the name of the work  ~ 
{Bold}{VARIABLE}key~{Bold}{Enter}{Enter} 
{DISPLAY OFF}including all revisions and future editions thereof; the 
rights to all subsidiary rights to said Work as defined in and 
subject to provisions in Paragraph  
{Mark Text}RROrights{Enter} 
 below; the right to copyright throughout the world in the name of 
the Author.  Copyright shall be taken out upon first publication by 
the Publisher at its own expense. 
{Enter}{Enter}{DISPLAY ON} 

This macro turns the display off and enters an automatic paragraph numbering code. It also marks the paragraph as a target for WordPerfect's auto-referencing function. In this case, the target name is "pubrites." The macro then starts the PUBLISHING RIGHTS paragraph, and pauses to allow you to enter the name of the work. It is printed on the page in bold. The second {Mark Text} interjects an auto-referencing code to the "rights" paragraph, which appears later in the contract.


WARRANTY.WPM (provided on the Applications Disk) {DISPLAY OFF}

{Date/Outline}P{Enter} 
{Mark Text}RTwarranty{Enter} 
{Tab}WARRANTY{Enter} 
Author represents and warrants that he/she is the author and 
proprietor and sole owner of all rights in the Work, that the Work is 
original except for such excerpts from copyrighted works as may be 
included with the permission of the copyright owner thereof, that it 
does not violate the right of privacy of or libel any person, that it 
does not infringe any copyright, trademark, patent, or any right of 
others, and that any formulas, processes, and directions originated or

devised by Author and used in the Work are safe and the Author has 
full power to make this agreement. 
{CHAR}key~Indemnity clause? (y/n)  ~ 
{CASE}{VARIABLE}key~~ 
y~clause~Y~clause~ 
n~return~N~return~ 
~ 
{LABEL}return~ 
{Enter}{Enter} 
{RETURN} 
{LABEL}clause~ 
  Author agrees to indemnify and hold harmless Publisher from all 
costs, expenses, and damages arising from any breach of such 
warranty.{Enter}{Enter} 

The WARRANTY.WPM macro starts by turning the display off and entering an automatic paragraph numbering code. The macro also marks the paragraph as a target for WordPerfect's auto-referencing function. In this case, the target name is "warranty." A conditional branch (using a {CASE} structure) asks if you want to include the indemnify clause. Pressing the y or Ykey inserts the text; pressing any other key skips over the text.

Of course, your contracts will contain different text and may require you to enter more variable information. Whenever you need to enter data or make a choice, add a {TEXT} instruction within the text, then plant the answer in the paragraph using {VARIABLE}x~, as shown in the previous examples.

Once the contract is complete, you should check to make sure that the paragraph and auto-referencing numbers are correct, then print it out for final review.

---

 Top Contents

WordPerfect 5.1 Macros and Templates
Electronic Edition
Copyright 1990, 1997, Gordon McComb.  All Rights Reserved.
First published by Bantam Electronic Publishing, 1990.
http://www.gmccomb.com/